dnl 
dnl Copyright (C) 2020,2021  CismonX <admin@cismon.net>
dnl 
dnl Copying and distribution of this file, with or without modification,
dnl are permitted in any medium without royalty,
dnl provided the copyright notice and this notice are preserved.
dnl This file is offered as-is, without any warranty.
dnl 

AC_PREREQ([2.69])
AC_INIT([ctlseqs], [0.1.0], [bug-report@cismon.net])
AC_CONFIG_SRCDIR([src/ctlseqs.c])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([foreign])
AM_EXTRA_RECURSIVE_TARGETS([install-man uninstall-man])
LT_PREREQ([2.4.2])
LT_INIT

# Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET

# Checks for compiler builtins and attributes.
m4_ifdef([AX_GCC_BUILTIN], [
    AX_GCC_BUILTIN(__builtin_expect)
    AX_GCC_BUILTIN(__builtin_unreachable)
])
m4_ifdef([AX_GCC_FUNC_ATTRIBUTE], [
    AX_GCC_FUNC_ATTRIBUTE(cold)
    AX_GCC_FUNC_ATTRIBUTE(hot)
])

# Checks for header files.
AC_CHECK_HEADERS([fcntl.h sys/ioctl.h termios.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_CHECK_HEADER_STDBOOL
AC_C_INLINE
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_REALLOC
AC_CHECK_FUNCS([strtol strtoul tcgetattr tcsetattr ioctl])

# Specify libtool library version.
m4_define([CTLSEQS_LT_CUR], [0])
m4_define([CTLSEQS_LT_REV], [0])
m4_define([CTLSEQS_LT_AGE], [0])
AC_SUBST([CTLSEQS_LT_VERSION], [CTLSEQS_LT_CUR:CTLSEQS_LT_REV:CTLSEQS_LT_AGE])

AC_CONFIG_FILES([
    Makefile
    include/Makefile
    doc/Makefile
    man/Makefile
    src/Makefile
    tests/Makefile
    examples/Makefile
])
AC_OUTPUT